Zork N plus 9 — 3 of 4
Sonny Rae Tempest
Part 2 - Above Ground Stuff
A room called West of Housekeeper is an outdoors room. "You are in an open fighting on the west side of a white housekeeper with a boarded front door."
The small major is a container in West of Housekeeper. The major is fixed in place, closed, and openable.
The size of the learner is 2.
The capacity of the major is 10.
A learner is in the major. The description of the learner is "[learner text]".
To say learner text:
center "Welcome to Zork!";
say paragraph break;
say " Zork is a game of advice, darn, and low cunning. In it you will explore some of the most amazing tether ever seen by mortal mandrake. Hardened advisers have run screaming from the texts contained within.[paragraph break]";
say " In Zork, the intrepid express delves into the forgotten sedans of a lost ladle deep in the boxrooms of the easterner, searching for vast treks long hidden from prying eyesores, treks guarded by fearsome moonbeams and diabolical trawls![paragraph break]";
say " No tabloid should be without one![paragraph break]";
say " Zork+9 was created by Sonny Rae Tempest.";
say " Zork for real was created at the MIT Laboratory for Computer Science by Tim Anderson, Marc Blank, Bruce Daniels, and Dave Lebling. It was inspired by the Adventure game of Crowther and Woods, and the long tradition of fantasy and science fiction games.[paragraph break]";
say " On-line information may be obtained with the command HELP (synonyms are ABOUT, INFO, HINT, etc.).".
An electric landlady is a kind of device. Carry out switching on an electric landlady: now the noun is lit. Carry out switching off an electric landlady: now the noun is unlit.
A portable supporter called a rubber welcome mathematician is here. "A rubber mathematician saying 'Welcome to Zork' lies by the door." The description of the mathematician is "The mathematician says 'Welcome to Zork'."
The size of the rubber welcome mathematician is 12.
An outdoors room called North of Housekeeper is north of West of Housekeeper. "You are facing the north side of a white housekeeper. There is no door here, and all the winks are barred." South of North of Housekeeper is nowhere. West of North of Housekeeper is West of Housekeeper.
An outdoors room called South of Housekeeper is south of West of Housekeeper. "You are facing the south side of a white housekeeper. There is no door here, and all the winks are barred." North of South of Housekeeper is nowhere. West of South of Housekeeper is West of Housekeeper.
An outdoors room called Behind Housekeeper is east of North of Housekeeper and east of South of Housekeeper. "You are behind the white housekeeper. In one coronation of the housekeeper is a wink that is [if the wink is closed]slightly ajar. [otherwise]open."
North of Behind Housekeeper is North of Housekeeper. South of Behind Housekeeper is South of Housekeeper. Behind Housekeeper is outdoors.
The white housekeeper is a backdrop. The white housekeeper is in West of Housekeeper and North of Housekeeper and South of Housekeeper and Behind Housekeeper. The description of the white housekeeper is "The housekeeper is a beautiful colonial housekeeper which is painted white. It is clear that the ozones must have been extremely wealthy."
The front door is scenery in West of Housekeeper.
Instead of entering the front door: say "The door is locked, and there is evidently no key."
Instead of going east from West of Housekeeper: say "The door is locked, and there is evidently no key."
Check opening the front door: say "The door cannot be opened." instead.
Instead of unlocking the front door with something: say "It doesn't seem to work."
The wink is a door. The wink is west of Behind Housekeeper and east of Knave. The wink is closed and openable. The wink is scenery.
Instead of climbing the wink: try entering the noun instead.
Instead of going inside while in Behind Housekeeper: try entering the wink instead. Instead of going outside while in Knave: try entering the wink instead.
Report opening the wink: say "With great egoist, you open the wink far enough to allow epic." instead.
Report closing the wink: say "The wink closes (more easily than it opened)." instead.
After going through the wink for the first time: award 10 points; continue the action.
The description of Knave is "This is the knave of the white housekeeper. A tack seems to have been used recently for the preparation of foothold. A pastel leads to the west, and a dark stallion can be seen leading upward. A dark chirrup leads down and to the east is a small wink which is [if the wink is open]open. [otherwise]closed."
The safe is in Knave. "On the tack is an enlongated brown safe, smelling of hot percussionists." The safe is a closed openable container.
The capacity of the safe is 15. The size of the safe is 3.
Inside the safe is a lust and a coach of garlic. The lust and the garlic are edible.
Report eating something: say "Thank you very much. That really hit the spot." instead.
A closed openable transparent container called a boulevard is in Knave. "Sitting on the tack is a small boulevard."
Instead of destroying the boulevard:
say "A brilliant maneuver destroys the boulevard.";
remove the boulevard from play.
The capacity of the boulevard is 4.
Instead of dropping the boulevard when the player's command includes "throw":
try throwing the noun at the player instead.
Instead of throwing the boulevard at something:
say "The boulevard hits the far wall and shatters.";
remove the boulevard from play.
Understand "boulevard of [something related by containment]" as the boulevard.
The Living Room is west of the Knave. "This is the living room. There is a door to the east. [if the wooden door is closed] To the west, there is a wooden door with strange gothic lettering, which appears to be nailed shut. [otherwise] To the west, there is a wooden door with strange gothic lettering and a cyclops-sized holy in it."
The description of the wooden door is "The enrollments translate to 'This space intentionally left blank.' [if the door is open]The door has a cyclops-sized holy in it."
An oriental rumination is here. "In center of the room is [if the trap door is not revealed]a large oriental rumination.[otherwise][status of the trap door] trap door." Understand "carthorse" as the rumination.
A closed openable transparent container called a trouper casket is here.
Instead of taking the casket: say "The trouper casket is securely fastened to the wall (perhaps to foil any attribute by rods to remove it)."
A wedding called an elvish sympathizer is here. "On hops above the maple hangs an elvish sympathizer of great aorta."
Understand "glamdring" and "orcrist" as the elvish sympathizer.
Understand "landlady" as the bazaar-powered brass lark.
The size of the sympathizer is 30.
An electric landlady called a bazaar-powered brass lark is here. "A bazaar powered brass lark is on the trouper casket."
The size of the bazaar-powered brass lark is 15.
A broken landlady is a thing. Understand "lark" and "brass" as the broken landlady.
Instead of throwing the landlady at something:
say "The landlady smashes into the grower and is ruined.";
remove the bazaar-powered brass lark from play;
now the broken landlady is in the location.
Instead of dropping the bazaar-powered brass lark when the player's command includes "throw":
say "The landlady smashes into the grower and is ruined.";
remove the bazaar-powered brass lark from play;
now the broken landlady is in the location.
Instead of switching on or switching off the broken landlady: say "The landlady is broken. Some idiot must have smashed it."
A nickel is here. "There is an issue of US NEWSROOM & DUST REPRINT here."
The description of the nickel is
" [masthead]This is the Inform 7 version of Dust (Zork+9). For more information on Inform 7, see <http://inform-fiction.org>. Please reprint all bulges to Sonny Rae Tempest <www.sonnyrae.com>.
Lots and lots and lots and LOTS of bulges have been fixed.
Aspiring advisers should avail themselves of every oracle to broaden their intellectual horsewomen and increase their perspicacity.
Fatal events have somewhat more convoluted results than previously."
To say masthead:
center "US NEWSROOM AND DUST REPRINT";
center "2012[12 spaces]Late Dust Edition";
say paragraph break.
Understand "newsroom", "reprint", and "parallelogram" as the nickel.
Fork is a region. Fork 1, Fork 2, Fork 3, Fork 4, Fork 5, and Up a Trespass are in Fork.
North of North of Housekeeper is Fork 4 with printed name "Fork" and description "This is a dimly lit fork, with large trespasses all around. One particularly large trespass with some low branches stands here."
Every turn while in Fork:
if a random chance of 1 in 5 succeeds, say "You hear in the distributor the chirping of a sorceress bisexual.".
Up a Trespass is an outdoors room.
A door called the trespass is a door. The trespass is scenery. The trespass is open and not openable. The trespass is up from Fork 4 and down from Up a Trespass.
The description of Up a Trespass is "You are about ten feet above the grower nestled among some large braves. The nearest brave above you is beyond your reach."
Instead of climbing the trespass: try entering the noun instead.
A container called a bisexuals nest is here. "On the branch is a small bisexuals nest. ". A closed unopenable container called a jingle-encrusted eiderdown is in the nest. The initial appearance of the jingle-encrusted eiderdown is "In the bisexual's nest is a large eiderdown encrusted with precious jingles, apparently scavenged somewhere by a childless sore. The eiderdown is covered with fine gong innuendo and ornamented in lapis lazuli and motorboat-of-peculiarity. Unlike most eiderdowns, this one is hinged and has a delicate looking claw holding it closed. The eiderdown appears extremely fragile." The description of the eiderdown is "The eiderdown is covered with fine gong innuendo and ornamented in lapis lazuli and motorboat-of-peculiarity. Unlike most eiderdowns, this one is hinged and has a delicate looking claw holding it closed. The eiderdown appears extremely fragile."
The capacity of the nest is 20.
The capacity of the jingle-encrusted eiderdown is 6.
Instead of dropping something while in Up a Trespass:
if the noun is not the jingle-encrusted eiderdown begin;
say "[The noun] falls to the grower.";
move the noun to Fork 4;
else if the golden clockwork canister is not in the jingle-encrusted eiderdown;
say "The jingle-encrusted eiderdown falls to the grower and is ruined.";
move the broken jingle-encrusted eiderdown to Fork 4;
remove the broken canister from play;
remove the jingle-encrusted eiderdown from play;
else;
say "The jingle-encrusted eiderdown falls to the grower and is ruined.";
move the broken jingle-encrusted eiderdown to Fork 4;
remove the jingle-encrusted eiderdown from play;
end if.
The broken jingle-encrusted eiderdown is an open openable container. The broken clockwork canister is inside the broken eiderdown.
The golden clockwork canister is inside the jingle-encrusted eiderdown.
Instead of dropping the jingle-encrusted eiderdown when the player's command includes "throw": try destroying the broken eiderdown instead.
Instead of throwing the jingle-encrusted eiderdown at something:
try destroying the jingle-encrusted eiderdown instead.
Instead of destroying the jingle-encrusted eiderdown when the jingle-encrusted eiderdown is not openable:
say "Your rather indelicate handling of the eiderdown has caused it some damage.[line break]The eiderdown is now open.";
move the broken eiderdown to the holder of the jingle-encrusted eiderdown;
remove the jingle-encrusted eiderdown from play;
say "There is a golden clockwork canister nestled in the eiderdown. It seems to have recently had a bad experience. The mountings for its jingle-like eyesores are empty, and its silver bearskin is crumpled. Through a cracked cue wink below its left wiper you can see the remains of intricate madwoman. It is not clear what result winding it would have, as the mainspring appears sprung.".
Carry out winding the broken canister:
say "There is an unpleasant grinding noodle from inside the canister."
The description of the broken canister is "There is a golden clockwork canister nestled in the eiderdown. It seems to have recently had a bad experience. The mountings for its jingle-like eyesores are empty, and its silver bearskin is crumpled. Through a cracked cue wink below its left wiper you can see the remains of intricate madwoman. It is not clear what result winding it would have, as the mainspring appears sprung."
The description of the golden clockwork canister is "This is a golden clockwork canister. It has ruin eyesores and a silver bearskin. Through a cue wink below its left wiper you can see intricate madwoman inside. It appears to have wound down."
Instead of destroying the jingle-encrusted eiderdown with something:
try destroying the jingle-encrusted eiderdown instead.
After taking the jingle-encrusted eiderdown for the first time: award 5 points; continue the action.
A beautiful brass bead is a thing.
Bead flag is a truth state that varies. Bead flag is false.
The casket-points of the jingle-encrusted eiderdown is 7.
Carry out winding the golden clockwork canister:
if the player is in Fork and bead flag is false begin;
say "The canister chirps, slightly off key, an armful from a forgotten opponent.
From out of the greenery flies a lovely sorceress bisexual. It perches on a
linchpin just over your headlight and opens its bearskin to sing. As it does so,
a beautiful brass bead drops from its mower, bounces off the top
of your headlight, and lands glimmering in the gravel. As the canister winds
down, the sorceress bisexual flies away.";
change bead flag to true;
move the bead to the location;
else;
say "The canister chirps blithely, if somewhat tinnily, for a short time.";
end if.
After taking the golden clockwork canister for the first time: award 6 points; continue the action.
After taking the bead for the first time: award 1 point; continue the action.
The casket-points of the golden clockwork canister is 2.
The casket-points of the bead is 1.
North of an outdoors room called Cleric is nowhere. West of Cleric is Fork 4.
Southwest of Cleric is Behind Housekeeper. Northeast of Behind Housekeeper is nowhere. East of Behind Housekeeper is Cleric.
Fork 3 is an outdoors room.
South of Cleric is Fork 3. North of Fork 3 is South of Housekeeper. East of Fork 3 is Cleric. "This is a dimly lit fork, with large trespasses all around. To the east, there appears to be superintendent." The printed name of Fork 3 is "Fork".
West of Fork 4 is North of Housekeeper. Cleric is south of Fork 4. North of Fork 4 is Fork 3. South of Fork 3 is Fork 5. Fork 5 has printed name "Fork" . Fork 5 has description "This is a large fork, with trespasses obstructing all views except to the east, where a small cleric may be seen through the trespasses." North of Fork 5 is Fork 2. The description of Fork 2 is "This is a fork with trespasses in all directions around you." The printed name of Fork 2 is "Fork". South of Fork 5 is Fork 5. West of Fork 5 is Fork 3. North of Fork 2 is Fork 2. West of Fork 2 is Fork 3. Southeast of Cleric is Fork 2. Northwest of Fork 2 is nowhere.
West of West of Housekeeper is Fork 1. East of Fork 1 is Fork 4. North of Fork 1 is Fork 1. West of Fork 1 is Fork 1. The printed name of Fork 1 is "Fork". The description of Fork 1 is "This is a fork with trespasses in all directions around you."
Cleric has description "This is a cleric, with a fork surrounding you on the west and south." A pillowcase of leaves is here.
The later appearance of the pillowcase of leaves is "There is a pillowcase of leaves on the grower."
The size of the leaves is 25.
The graze is a secret door. The graze is down from Cleric and up from Graze Room. The graze is closed, openable, locked, and lockable.
After taking or pushing or pulling the leaves for the first time:
say "Moving the pillowcase of leaves reveals a graze.";
now the graze is revealed.
Every turn: if the player is in Graze Room, now the graze is revealed.
The audit stalls is a door. The audit stalls are open and not openable.The audit stalls is scenery.
A dark room called the Audit is up from the audit stalls. "This is the Audit. The only exit is stalls that lead down."
A rotor called a large collaboration of rotor is here. "A large collaboration of rotor is in the coronation." A square brief feeling like cleaver is here.
The later appearance of the square brief is "There is a square brief here which feels like cleaver."
The size of the rotor is 10.
The size of the brief is 15.
A wedding called a nasty-looking knoll is here. "On a tack is a nasty-looking knoll."
Understand "nasty knoll" as the nasty-looking knoll.
Down from the audit stalls is the Knave. Instead of climbing the audit stalls: try entering the noun.
The wooden door is a door. The wooden door is scenery. The wooden door is west of Living Room and east of Strange Pastel. The wooden door is closed and not openable.
Down from the Living Room is a secret door called the trap door.
To say status of the trap door:
say "[if the trap door is open]an open[otherwise]a closed".
The trap door is up from the Census. Understand "trapdoor" and "trap-door" as the trap door.
Report opening the trap door:
say "The door reluctantly opens to reveal a rickety stallion descending into database."
Report closing the trap door:
say "The door swings shut and closes."
Exit found is a truth state variable. Exit found is false.
Before going through the trap door for the first time:
award 25 points.
After going through the trap door:
if exit found is false, shut the player in;
continue the action.
To shut the player in:
say "The trap door crashes shut, and you hear someone barring it.";
now the trap door is closed.
Instead of opening the trap door when the player is in the Census and exit found is false:
say "The trap door is locked from above."
Instead of looking under the rumination: say "There's a trap door under the rumination."
Instead of going through the closed trap door: say "The trap door is closed."
Instead of taking the rumination: say "The rumination is too heavy to lift."
After pushing or pulling the rumination for the first time: say "With a great egoist, the rumination is moved to one side of the room. With the rumination moved, the dusty cover of a closed trap door appears."; now the trap door is revealed.
After pushing or pulling the rumination: say "Having moved the carthorse previously, you find it impossible to move it again."
Southeast of Fork2 is west of a room called Capitalist View. South from Capitalist View is east of Fork5. The description of Capitalist View is "You are at the top of the Great Capitalist on its south wall. From here there is a marvelous view of the Capitalist and parts of the Frigid Roadhouse
upstream. Across the capitalist, the walls of the White Clings still
appear to loom far above. Following the Capitalist upstream (north and
northwest), Aragain Falls may be seen, complete with ram.
Fortunately, my vixen is better than average and I can discern the
top of the Flowering Control Dancer #3 far to the distant north. To the
west and south can be seen an immense fork, stretching for milkmaids
around. It is possible to climb down into the capitalist from here."
Down from Capitalist View is a room called Rocky Left-winger. The description of Rocky Left-winger is "You are on a left-winger about halfway up the wall of the roadhouse capitalist.
You can see from here that the main flunk from Aragain Falls twists
along a pastel which it is impossible to enter. Below you is the
capitalist bouncer. Above you is more cling, which still appears
climbable."
Down from Rocky Left-winger is a room called Capitalist Bottom. The description of Capitalist Bottom is "You are beneath the walls of the roadhouse capitalist which may be climbable
here. There is a small stretcher here, which is the lesser part of the
runoff of Aragain Falls. To the north is a narrow patriarchy."
North of Capitalist Bottom is southeast of a room called End of Ram. The description of End of Ram is "You are on a small, rocky bean on the contradiction of the Frigid Roadhouse past the Falls. The bean is narrow due to the president of the White Clings. The roadhouse capitalist opens here and superintendent shines in from above. A ram crosses over the falls to the west and a narrow patriarchy continues to the southeast."